隧道开挖的工程实例

/PREP7
k,1,0,0,
k,2,5.966,-0.642
k,3,5.255,2.896,
k,4,0,6
k,5,-5.255,2.896,
k,6,-5.966,-0.642
k,7,-5.82,-2
k,8,5.82,-2

MP,EX,1,14e9   
MP,NUXY,1,0.23
MP,DENS,1,2560
TB,DP,1,,,0
TBMODIF,1,1,1.2e6  
TBMODIF,1,2,47.7
TBMODIF,1,3,47.7

!开挖岩体单元，为便于进行开挖，故选取了两种单元
ET,1,PLANE42
KEYOPT,1,3,2
!周围岩体单元
ET,2,PLANE42
KEYOPT,2,3,2




!生成开挖轮廓
larc,2,4,3         
larc,4,6,5         
larc,3,5,4         
lstr,6,7            
lstr,7,8
lstr,2,8

lovlap,all

NUMMRG,kp, , , ,LOW
NUMCMP,KP   
NUMCMP,LINE

!将轮廓线叠合
lcomb,3,4,0
lcomb,6,5,0
lcomb,1,7,0

NUMMRG,kp, , , ,LOW
NUMCMP,KP   
NUMCMP,LINE

!生成周围边界
k,6,-30,-30
k,7,30,-30
k,8,30,30
k,9,-30,30           
lstr,6,7            
lstr,7,8
lstr,8,9
lstr,6,9

lstr,2,8            
lstr,3,9
lstr,4,6
lstr,5,7

!生成开挖面

al,1,2,3,4,

!生成围岩面
al,2,5,11,12
al,3,6,9,12
al,4,7,10,9
al,1,8,11,10


!隧道周边网格划分时的线段数
lsel,s,,,1,4,1

lesize,all,,,15,,,,,1
lsel,s,,,5,8,1

lesize,all,,,15,,,,,1


!围岩网格划分时的线段数

lsel,s,,,9,12,1

lesize,all,,,15,3,,,,1



!开挖材料属性赋予
asel,s,,,1
AATT,1, 1,1,,  

!围岩材料属性赋予
asel,s,,,2
AATT,1,1,2,,  

asel,s,,,3
AATT,1,1,2,,

asel,s,,,4
AATT,1,1,2,,

asel,s,,,5
AATT,1,1,2,,


!划分开挖单元
ASEL,S,TYPE,,1
mshape,0,2D      
mshkey,0  
AMESH,ALL,

!划分围岩单元

ASEL,S,TYPE,,2
mshape,0,2D      
mshkey,1  
AMESH,ALL,


FINISH

/SOLU
ANTYPE,STATIC,NEW

NLGEOM,ON
NROPT,FULL
SSTIF,ON

!施加边界条件,底边固定.四边梯形载荷.

LSEL,S, , ,5
DL,ALL, ,all,0
lsel,s,,,7
sfl,7,pres,10.83e6
lsel,s,,,8
sfl,8,pres,18.76e6,17.84e6
lsel,s,,,6
sfl,6,pres,18.76e6,17.84e6

ALLSEL,ALL


ACEL,0,10,0

TIME,1
DELTIM,0.025,0.0001,0.05
AUTOTS,ON
LNSRCH,ON
PRED,ON

!初始地应力计算

allsel,all
solve

!!开挖模拟
ESEL,S,type,,1

EKILL,ALL


ALLSEL,ALL
TIME,2
SOLVE