大家一起来学习ANSYS（有关于耦合的讨论）

我还没用过，大家一起学习啊，

本人也是初学,感觉ansys比其他的大部分软件都要难,毕竟是全英文的.
但是对作科研来说,还是最可靠的.

TDV也全英文，也学习瞎吧

ansys对于搞局部应力分析很不错，但是对于工程搞设计不太适应。
感觉ansys在作非线性分析这一块不是很好，abqus在非线性方面做的不错，不过前后处理不是很好。

发个命令流大家共同研究一下，是耦合方面的，既然是共同提高，打击就要共同研究一下吧
/prep7
eg=2e5
ag=140
eh=4e4
r0=9345
yyl=200000
et,1,link8
et,2,solid95
r,1,ag,yyl/eg/ag*1.036258
r,2
mp,ex,1,eg
mp,prxy,1,0.3
mp,ex,2,eh
mp,prxy,2,0.2
blc4,,,100,200,3000
/view,1,1,1,1
/ang,1
vplot
!------------定义力筋线
ksel,all
*get,kp0,kp,0,num,max
lsel,none
k,kp0+1,50,160
k,kp0+2,50,160,3000
k,kp0+3,50,800,1500
larc,kp0+1,kp0+2,kp0+3,r0
kdele,kp0+3
*get,line1,line,0,num,min
!-------------定义约束
lsel,s,loc,z,0
lsel,r,loc,y,0
dl,all,,uy
lsel,s,loc,z,3000
lsel,r,loc,y,0
dl,all,,all
allsel,all
!-----------单元划分
lsel,s,,,line1
latt,1,1,1
lesize,all,,,50
lmesh,all
vsel,all
vatt,2,2,2
lsel,s,loc,z,0
lsel,r,loc,y,10,140
lesize,all,,,8
lsel,s,loc,z,0
lsel,u,loc,y,10,140
lesize,all,,,4
lsel,s,loc,y,0
lsel,r,loc,x,0
lesize,all,,,50
vsweep,all
allsel,all
!耦合自由度
lsel,s,,,line1
nsll,s,1
cm,cmljnod,node
*get,max1,node,0,count
*dim,ojd,,max1
*dim,jd,,max1
*get,nod1,node,0,num,min
ojd(1)=nod1
*do,i,2,max1
ojd(i)=ndnext(ojd(i-1))
*enddo
allsel,all
nsel,all
cmsel,u,cmljnod
*do,i,1,max1
nod1=ojd(i)
j=nnear(nod1)
jd(i)=j
*enddo
nsel,all
ji=1
*do,i,1,max1
cp,ji,ux,ojd(i),jd(i)
cp,ji+1,uy,ojd(i),jd(i)
cp,ji+2,uz,ojd(i),jd(i)
ji=ji+3
*enddo
allsel,all
ji=
i=
max1=
nod1=
ojd=
jd=
j=
ag=
eg=
eh=
kp0=
r0=
yyl=
line1=

finish
/solu
solve
finish
/post1
pldisp,1
etable,sigi,ls,1
plls,sigi,sigi,1
我对耦合的部分有些疑问，有人愿意给出解释么，谢谢

在有限元程序中有所谓的同位移约束，或称主从约束。耦合正是用来做这种事情。实际上耦合上ansys里约束方和的一个简化形式。重用约束方程能够定义更复杂的两个结点之间的关系，不在局限于相同的位移，而是可以定义两个结点之间位移的具体数学关系式

!耦合自由度
lsel,s,,,line1
nsll,s,1
cm,cmljnod,node !将钢筋节点创建为一个组件
*get,max1,node,0,count !钢筋节点个数
*dim,ojd,,max1
*dim,jd,,max1
*get,nod1,node,0,num,min !钢筋上最小节点的编号
ojd(1)=nod1
*do,i,2,max1
ojd(i)=ndnext(ojd(i-1)) !钢筋节点编号，ndnext是下一个节点编号
*enddo
!选择实体节点
allsel,all
nsel,all
cmsel,u,cmljnod
!寻找耦合节点编号
*do,i,1,max1
nod1=ojd(i)
j=nnear(nod1) !离该节点距离最近的节点编号
jd(i)=j
*enddo
nsel,all
ji=1
!循环耦合，三方向耦合。
*do,i,1,max1
cp,ji,ux,ojd(i),jd(i)
cp,ji+1,uy,ojd(i),jd(i)
cp,ji+2,uz,ojd(i),jd(i)
ji=ji+3
*enddo

我明白了，真的谢谢斑竹

关于ANSYS载荷的考虑

有限元网格划分的基本

我在学校毕业设计时用过，但确实很难学阿

谢谢啊，请问啊，很是感动