箱梁温度梯度的模拟[ANSYS]-桥头堡论坛

fengpei001 发表于 2008-12-13 21:37:38

箱梁温度梯度的模拟

现在在做一个箱梁温度分析的作业，但是有一些不明白的地方，
对于温度荷载的施加通常有两种方式：
其一是直接法，就是利用既可用于结构分析又可用于热分析的单元直接求解得出相应的应力；
其二是间接法：先采用热力学单元将温度转化为应力，然后将其施加到结构上(相当于外荷)，并将相应的热力学单元用结构力学单元替代，并求解得出相应的结构内力(应力)；
对于梁单元，如188，189我已经知道如何加温度效应，但是BFE只能施加线性的温度梯度，对于实体或者板壳单元的箱梁温度梯度的施加不是很明白，特别是如何施加非线性温度梯度，希望高手能发个例子上来，指导一二。
现贴一个简单的188单元，施加线性温度梯度荷载的例子（参看《基于ANSYS的桥梁结构分析》），以抛砖引玉。
fini
/cle
/prep7
height=1.5
uptemp=30
botemp=730
midtemp=(30+730)/2
temp_gradient=(uptemp-midtemp)/(height/2)
temp_z1=midtemp+temp_gradient
et,1,beam188
sectype,1,beam,i,,0
secoffset,cent
secdata,1,1,height,0.1,0.1,0.1,0,0,0,0
k,1
k,2,10
k,3,,10
l,1,2
latt,,,1,,3,,1
esize,1
lmesh,all
/eshape,1
/view,1,1,2,3
bfe,all,temp,1,midtemp,midtemp,temp_z1,midtemp
bfe,all,temp,5,midtemp,temp_z1
/pbf,temp,,1
eplo

[ 本帖最后由 fengpei001 于 2008-12-13 21:38 编辑 ]

fengpei001 发表于 2008-12-16 13:29:00

怎么没有反应呢，自己先顶一个。

fengpei001 发表于 2008-12-16 21:47:28

可以采用ANSYS耦合场求解能力。首先进行热分析求解温度分布，再进行结构分析就可以读入热分析求解任意时刻的温度分布作为结构的温度荷载。也就是上述的间接法。可是，如何才能得到自己想要的温度分布模式。现在学习中。。。。。。希望。。。。先发一个《ANSYS分析指南》，以便共同学习！

我是飞沙 发表于 2009-5-10 21:24:11

请问楼主，日照温度是不是可以采用体荷载，本人在施加温度荷载时，却只能加到一个侧面上（如x方向），为什么不能同时加到y方向上呢？

murongcao 发表于 2010-4-27 09:12:26

本帖最后由 murongcao 于 2010-4-27 09:18 编辑

可以用表格输入的方发来实现任何温度模式的输入哦～～
附件是我对一个小箱梁进行的折线温度加载，温度加载实现了折线分布
不过结构应力～～我还没有分析明白。

下面是命令流请多指教～～

fini
/CLEAR
/prep7
/title,Anlyse of kongxinban-side
!单位系统采用mm，N，MPa
et,1,42
ET,2,65
et,3,45 !模拟支座
MP,EX,1,3.45e4 !C50
MP,PRXY,1,0.2
MP,DENS,1,2600e-12
MP,ALPX,1,1e-5
MP,EX,2,2e5 !模拟支座
MP,PRXY,2,0.3
MP,DENS,2,7800e-12
MP,ALPX,2,1e-5
r,1
K,1, 542.5 , 0
K,2, 782.5 , 0
K,3, 782.5 , 230
K,4, 782.5 , 575
K,5, 702.5 , 655
K,6, 702.5 , 695
K,7, 757.5 , 750
K,8, 757.5 , 800
K,9, -1182.5 , 800
K,10, -1182.5 , 690
K,11, -782.5 , 600
K,12, -782.5 , 230
K,13, -782.5 , 0
K,14, -542.5 , 0
K,15, 542.5 , 110
K,16, 662.5 , 230
K,17, 662.5 , 440
K,18, 512.5 , 640
K,19, 0 , 680.009
K,20, -512.5 , 640
K,21, -662.5 , 440
K,22, -662.5 , 230
K,23, -542.5 , 110

L,1,2
*repeat,13,1,1
L,14,1
L,15,16
*repeat,3,1,1
larc,18,20,19
L,20,21
*repeat,3,1,1
L,23,15
L,1,15
L,16,3
L,18,5
L,11,20
L,12,22
L,14,23

AL,15,16,17,18,19,20,21,22
AL,14,23,22,28
AL,11,27,20,19,26
AL,25,4,3,24,16,17
AL,27,21,28,13,12
AL,24,2,1,23,15
AL,5,6,7,8,9,10,26,18,25
ALLSEL,ALL

esize,50
asel,s,,,5,6
asel,a,,,2
LCCAT,12,13
LCCAT,1,2
mshape,0,2d
mshkey,1
amesh,all

ALLSEL,ALL
LSEL,S,,,19,21,1
LCCAT,ALL
LSEL,S,,,15,17,1
LCCAT,ALL
amesh,1

ALLSEL,ALL
LCCAT,20,19
LCCAT,16,17
LCCAT,3,4
amesh,3,4

ALLSEL,ALL
LSEL,S,,,5,7
LCCAT,ALL
LSEL,S,,,10,18,8
LSEL,A,,,25,26
LCCAT,ALL
amesh,7
ALLSEL,ALL
LDELE,29,37,1

KGEN,2,14,,,,-60
L,14,24
ADRAG,14,,,,,,29
TYPE,1
amesh,8
allsel,all

k,100
k,101,,,-500
k,102,,,7500
lstr,100,101
lstr,100,102
asel,s,,,2,6,1
cm,a1,area
asel,s,,,1,7,1
cm,a2,area
/VIEW,1,1,1,1

type,2
mat,1
ESIZE,200
allsel,all
vdrag,7,,,,,,34
cmsel,s,a1
vdrag,all,,,,,,34
ESIZE,100
cmsel,s,a2
vdrag,all,,,,,,33
type,3
mat,2
ESIZE,100
allsel,all
vdrag,8,,,,,,33

allsel,all
esel,s,type,,1
aclear,all

allsel,all
NUMCMP,ALL
NUMMRG,ALL,,,,LOW
eplot
/dist,1,0.729,1
/triad,ltop
/image,save,16m_kongxinban_3d.bmp
SAVE

/solu
time,1
tref,0 !定义原始温度
*dim,htemp,table,3,1,1,Y,TEMP, !定义表格数据模拟梯度温度
htemp(1)=0,0,15
htemp(1,0)=0,400,800

NSEL,S,LOC,Y,0,800
BF,ALL,TEMP, %HTEMP% !调用表格数据加载梯度温度
/PBf,temp,,1 !显示温度荷载
/VIEW,1,1,1,1
/ANG,1
/REP,FAST

allsel,all
nsel,s,loc,y,-60
nsel,r,loc,z,-200,-500
d,all,all !定义支座约束
nsel,s,loc,Z,7500
d,all,uz !定义跨中对称约束
allsel,all
outpr,basic,last
solve
/dscale,1,1 !显示图形中不显示变形

shunmei_sm_6156 发表于 2015-3-9 21:42:22

终于找到了一个日照温度的，哈哈

页: [1]

桥头堡's Archiver

箱梁 温度梯度的模拟

箱梁温度梯度的模拟